Опишите на русском языке или на одном из языков программирования алгоритм подсчета суммы всех отрицательных элементов заданного целочисленного массива размером 30 элементов.

⎕←+/0⌊⎕←¯32769+?30⍴65536

На обработку поступает положительное целое число, не превышающее 10⁹. Нужно написать программу, которая выводит на экран сумму цифр этого числа, меньших 7. Если в числе нет цифр, меньших 7, требуется на экран вывести 0.

⎕←{D←(10⍴10)⊤⍵ ⋄ +/(D<7)/D}⎕

Опишите на русском языке или на одном из языков программирования алгоритм получения из заданного целочисленного массива размером 30 элементов другого массива, который будет содержать модули значений элементов первого массива.

⎕←|⎕←¯10001+?30⍴20001

Дан целочисленный массив из 30 элементов. Элементы массива могут принимать значения от 0 до 1000. Опишите алгоритм, который позволяет подсчитать и вывести среднее арифметическое элементов массива, имеющих нечетное значение.

⎕←{{(+/⍵)÷⍴⍵}(2|⍵)/⍵}⎕←¯1+?30⍴1001

Задача 9209: Дан массив, содержащий неотрицательные целые числа. Если сумма всех элементов массива чётная, нужно вывести количество чётных (по значению) элементов массива, если нечётная – количество нечётных.

⎕←{+/(2|+/⍵)=2|⍵}⎕←¯1+?10⍴101

Задача 7682: Количество пар соседних элементов массива (состоящего из 20 чисел от -10000 до 10000), сумма которых делится на 2, но не делится на 4.

⎕←{+/2=4|(1↓⍵)+¯1↓⍵}⎕←¯10001+?20⍴20001